Bryan Chung

I bought this simple Phidget 8/8/8 interface kit with 8 digital inputs, 8 digital outputs and 8 analog inputs. For projects that require only simple input and output control, it is a handy choice to replace the soon obsolete EZIO board. It has a USB interface and API for most major programming languages, like C/C++, Java, ActionScript.

Since it has a Java API, i.e. the phidget21.jar libary, it can be easy to use it in Processing. From the example, I adopt it by placing the jar file in the code folder of the Processing sketch. The first exercise is to switch on/off an LED.

The library comes with a lot of async. features. In the exercise, I ignore them for the moment in order to simplify everything.

import com.phidgets.*;
import com.phidgets.event.*;

InterfaceKitPhidget ik;
boolean led;

void setup() {
  size(200,200);
  smooth();
  noStroke();
  fill(100);
  println(Phidget.getLibraryVersion());
  try {
    ik = new InterfaceKitPhidget();
    ik.openAny();
    ik.waitForAttachment();
  }
  catch (Exception e) {
    println(e.toString());
  }
  led = false;
}

void draw() {
  background(0);
  if (led) {
    fill(255,255,0);
  }
  else {
    fill(100);
  }
  ellipse(width/2,height/2,100,100);
}

void mousePressed() {
  led = !led;
  try {
    ik.setOutputState(0,led);
  }
  catch (Exception e) {
    println(e.toString());
  }
}

void stop() {
  try {
    ik.close();
  }
  catch (Exception e) {
    println(e.toString());
  }
  ik = null;
}